Godot 联机

用高层多人 API 或 ENetConnection 搭主机权威联机，并验证客户端看到的和主机一致。

范围

先查内置

• 引擎不提供：大厅、好友邀请、客户端预测、校正重放、按接收者的流量预算
• ENet 不做 NAT 穿透，公网玩家连家用主机要转发 UDP 端口
• 免转发：WebRTCMultiplayerPeer 配 STUN TURN 和自建信令服务，原生平台装 webrtc-native 扩展
• 或者接第三方平台的传输

做法

建连

extends Node

const PORT := 7000
const MAX_CLIENTS := 3

func host() -> Error:
	var peer := ENetMultiplayerPeer.new()
	var error := peer.create_server(PORT, MAX_CLIENTS)
	if error != OK:
		return error
	multiplayer.multiplayer_peer = peer
	return OK

func join(address: String) -> Error:
	var peer := ENetMultiplayerPeer.new()
	var error := peer.create_client(address, PORT)
	if error != OK:
		return error
	multiplayer.multiplayer_peer = peer
	return OK

• create_client 返回 OK 只代表开始连接
• 连上等 MultiplayerAPI.connected_to_server，失败看 MultiplayerAPI.connection_failed
• 服务器 peer id 固定是 1

主机校验

客户端只发意图，结果由主机算：

extends Node

const OPEN_RANGE := 3.0

var players: Dictionary[int, Node3D] = {}
var chest_position := Vector3.ZERO
var opened := false

func request_open() -> void:
	open_chest.rpc_id(1)

@rpc("any_peer", "call_local", "reliable")
func open_chest() -> void:
	if not multiplayer.is_server() or opened:
		return
	var player: Node3D = players.get(multiplayer.get_remote_sender_id())
	if player == null or player.global_position.distance_to(chest_position) > OPEN_RANGE:
		return
	opened = true

• 主机本人也是玩家时要 call_local，否则主机自己点了没反应
• 身份只取 MultiplayerAPI.get_remote_sender_id，不信参数里的玩家 id
• get_remote_sender_id 只在 RPC 同步执行期间有效，await 后为 0，先存局部变量
• 扣费类请求带版本号或请求 id，防止重复请求按两次算

• 高频数据显式写传输模式，否则全走可靠
• 两端 RPC 配置要一致，引擎按全部 RPC 的校验和比对

传输模式

• 不可靠和可靠走不同 ENet 通道，互相没有先后保证
• 后发的不可靠快照可能先于可靠的生成包到达，接收方容忍实体暂时不存在
• 通道号大于 0 时建独立通道，慢消息不挡快消息
• 不可靠数据单包控制在 1364 字节内：MTU 1392 减 ENet 头 4 字节和分片头 24 字节

复制

extends MultiplayerSpawner

@export var enemy_scene: PackedScene

func _ready() -> void:
	spawn_function = _create_enemy

func _create_enemy(data: Dictionary) -> Node:
	var enemy: Node3D = enemy_scene.instantiate()
	enemy.position = data["position"]
	return enemy

主机调用 MultiplayerSpawner.spawn，spawn_function 在所有对端执行，返回未入树的节点。

后加入

Spawner 生成的实体和 Synchronizer 状态会补发给新对端。下列不补发，要自己放进全量状态：

• 判断标准：事件发生 10 秒后进房的人眼里，它不是初始值，就属于状态
• 逐项检查表见 references/sync-checklist.md

表现同步

AI 和玩法脚本只在权威端跑时，动作、隐藏、节点生成都只有主机看得见。

• 新增技能或交互时同时写一条客户端断言，漏同步在主机上看不出来

自建传输与预测

两进程验证

godot --headless --path . res://tests/net_smoke.tscn -- --host 27400
godot --headless --path . res://tests/net_smoke.tscn -- --join 127.0.0.1 27400

• 用 OS.get_cmdline_user_args 读 -- 之后的参数
• 主机日志出现就绪标记后再起客户端
• 两边各自断言并以退出码报告，只看主机通过不算验收
• 本机回环没有延迟丢包，给传输层包一层加延迟、抖动、丢包
• 超时按两端加载耗时之和留余量

陷阱

参考

• references/csharp.md：C# 项目先读，本文各节示例的 C# 写法
• references/sync-checklist.md：新增同步内容时的逐项检查
• references/custom-transport.md：ENetConnection 的发送、超时、断开语义
• references/authoritative-movement.md：预测、校正、重放的不变量
• https://docs.godotengine.org/en/stable/tutorials/networking/high_level_multiplayer.html
• https://docs.godotengine.org/en/stable/classes/class_multiplayersynchronizer.html
• https://docs.godotengine.org/en/stable/classes/class_enetconnection.html