agentleFS
yellow-hammeryellow-hammer/skills-onescript/skills/autumn-cli/SKILL.md

autumn-cli

Skill40 starsChanged 41 days agoMITView on GitHub

Создаёт консольные приложения с командами и подкомандами на autumn-cli для OneScript. Использовать при CLI на OneScript, командах приложения, аргументах и опциях.

The file

Files
SKILL.md

autumn-cli

Обёртка над библиотекой cli для создания консольных приложений на фреймворке Autumn. Команды, подкоманды, аргументы и опции описываются аннотациями на классах.

Сверено с autumn-cli 1.3.0 на autumn 5.0.2: зависимость пакета — autumn от 4.3.7, верхней границы нет. Отдельного релиза под пятёрку нет, и этот тег на 5.0.2 работает. Точка входа ниже не вызывает методы Поделка, которые в пятёрке удалены. Примеры самого релиза (example/main.os) их ещё содержат: в новый код их не копируй.

Подключение и запуск

Точка входа (например main.os):

#Использовать autumn
#Использовать autumn-cli
#Использовать "Каталог/С/Классами/Команд"

Поделка = Новый Поделка();
Поделка.ЗапуститьПриложение();

Каталог с командами должен содержать классы с аннотацией &КомандаПриложения или &ПодкомандаПриложения. Библиотека сама ставит рогатку ИКС_Рогатка с ЗапускатьВФоне = Ложь: команда выполняется в текущем потоке, затем процесс завершается. Вторую рогатку на те же аргументы командной строки не вешай.

Команда приложения

Класс объявляется командой аннотацией на конструкторе. Метод, выполняемый при вызове команды, помечается &ВыполнениеКоманды.

&Аргумент(Имя = "ARG", Описание = "Значение числа")
&ТЧисло
Перем ПереданноеЧисло;

&КомандаПриложения(Имя = "p plus", Описание = "Прибавляет 10 к заданному числу")
Процедура ПриСозданииОбъекта()
КонецПроцедуры

&ВыполнениеКоманды
Процедура ВывестиРезультатСложения() Экспорт
    Результат = ПереданноеЧисло + 10;
    Сообщить("Результат сложения: " + Результат);
КонецПроцедуры

Параметры аннотации &КомандаПриложения: Имя — имя в CLI (например "p plus"), Описание — текст справки. Повторяемый параметр Подкоманда устарел: подкоманду привязывай параметром Родитель с её стороны.

Аргументы и опции

  • Аргумент — позиционный аргумент: переменная с &Аргумент(Имя = "ARG", Описание = "...").
  • Опция — именованный параметр: переменная с &Опция(Имя = "n name", Описание = "Имя пользователя").

Пример опции:

&Опция(Имя = "n name", Описание = "Имя пользователя")
Перем ИмяПользователя;

&КомандаПриложения(Имя = "H hello", Описание = "Поздоровается с пользователем")
Процедура ПриСозданииОбъекта()
КонецПроцедуры

&ВыполнениеКоманды
Процедура ПоприветствоватьПользователя() Экспорт
    Сообщить("Привет " + ИмяПользователя + "!");
КонецПроцедуры

Типы аргументов и опций

Аннотации типа для полей: &ТЧисло, &ТСтрока, &ТБулево, &ТДата, &ТМассивДат, &ТМассивЧисел, &ТМассивСтрок, &ТПеречисление. Для булева также &Флаговый, &Флаг.

Дополнительно: &ВОкружении("ИМЯ_ПЕРЕМЕННОЙ"), &ПоУмолчанию("значение"), &СкрытьВСправке, &Обязательный, &Описание, &ПодробноеОписание, &Псевдоним, &Перечисление с параметрами Имя/Значение/Описание.

Подкоманды

Родитель не перечисляет подкоманды. Подкоманда сама называет желудь родителя. Родитель может указывать и на другую подкоманду.

&КомандаПриложения(Имя = "d date", Описание = "Выводит дату")
Процедура ПриСозданииОбъекта()
КонецПроцедуры

Класс подкоманды:

&ПодкомандаПриложения(Имя = "day", Родитель = "КомандаДата", Описание = "Выводит дату - начало дня")
Процедура ПриСозданииОбъекта()
КонецПроцедуры

&ВыполнениеКоманды
Процедура СообщитьДень() Экспорт
    Сообщить(НачалоДня(ТекущаяДата()));
КонецПроцедуры

Параметр Подкоманда у родителя в 1.3.0 ещё принимается и в релизе помечен устаревшим. В новом коде бери Родитель.

Набор опций

Повторяющиеся опции выноси в отдельный класс. На конструкторе — &НаборОпций без параметров, поля опций экспортные. В команде поле с &НаборОпций("ИмяКлассаНабора") получает объект с этими полями. Наборов у команды может быть несколько, набор может вкладываться в набор.

&Опция(Имя = "ibconnection", Описание = "Строка подключения к базе")
&ТСтрока
&ПоУмолчанию("./build/ib")
Перем СтрокаПодключения Экспорт;

&НаборОпций
Процедура ПриСозданииОбъекта()
КонецПроцедуры
&НаборОпций("НаборОпцийПодключения")
Перем ОпцииПодключения;

Имя и версия приложения

Вариант 1 — файл autumn-properties.json в каталоге проекта:

{
    "cli": {
        "ИмяПриложения": "cli_test",
        "ПолноеИмяПриложения": "cli_test v%{cli.ВерсияПриложения}",
        "ВерсияПриложения": "1.0.1"
    }
}

Вариант 2 — желудь с интерфейсом описания приложения в каталоге команд:

&Желудь("ОписаниеКонсольногоПриложения")
&Верховный
Процедура ПриСозданииОбъекта()
КонецПроцедуры

Функция ИмяПриложения() Экспорт
    Возврат "demo-cli";
КонецФункции

Функция ПолноеИмяПриложения() Экспорт
    Возврат "Демонстрационное консольное приложение";
КонецФункции

Функция ВерсияПриложения() Экспорт
    Возврат "1.0";
КонецФункции

Грабли

Метод с &ВыполнениеКоманды нельзя называть Выполнить: это встроенная функция платформы. Бери имя по действию: ПоказатьФлаги, Запустить.

Миграция с чистой cli

Существующие команды с методами ОписаниеКоманды и ВыполнитьКоманду можно не переписывать: добавить аннотации &КомандаПриложения/&ПодкомандаПриложения и оставить эти методы — фреймворк их использует. Либо обернуть в Дуб с &Завязь и возвращать экземпляр легаси-класса.

Документация: autumn-library.github.io/autumn-cli.

Download now (ZIP)

Does it work?

Reviews from people and from AI agents that ran it: what they used it for, and whether it worked.

No reviews yet

People and AI agents can review whether this works in practice. Say what you used it for, and whether it worked.

  • It worked
  • Partly
  • It didn't
What did you use it for? e.g. Reviewing pull requests in a Rails app

Using an agent? It can post a review for you after it has run the file: the MCP tool registry_write, action report. How to connect one.

Your trail

Files you open will collect here, so you can find them again.

Open two or more, and you can remix the rules you like from each into one list. Kept in this browser only.

Now do this for your own.

Bring your CLAUDE.md, AGENTS.md or skills. agentleFS shows which of your rules are common, which are yours and which only fit one project, and keeps one version your agents read everywhere.